백업과 복구

CREATE DATABASE MssqlLabBak;
ALTER DATABASE MssqlLabBak SET RECOVERY FULL;
GO

USE MssqlLabBak;
GO
CREATE TABLE dbo.T_LOG (
    num      int IDENTITY PRIMARY KEY,
    memo     nvarchar(100),
    reg_date datetime2(0) NOT NULL DEFAULT SYSDATETIME()
);
INSERT INTO dbo.T_LOG (memo) VALUES (N'첫 번째'), (N'두 번째'), (N'세 번째');

ALTER DATABASE MssqlLabBak SET RECOVERY SIMPLE;
GO
BACKUP LOG MssqlLabBak TO DISK = 'C:\mssql-lab-backup\x.trn';

-- 전체 — 그 시점의 데이터베이스 전부입니다.
BACKUP DATABASE MssqlLabBak
TO DISK = 'C:\mssql-lab-backup\Lab_full.bak'
WITH INIT, NAME = N'전체';

-- 차등 — 마지막 전체 백업 뒤에 바뀐 것만입니다.
BACKUP DATABASE MssqlLabBak
TO DISK = 'C:\mssql-lab-backup\Lab_diff.bak'
WITH INIT, DIFFERENTIAL, NAME = N'차등';

-- 로그 — 마지막 로그 백업 뒤의 기록입니다.
BACKUP LOG MssqlLabBak
TO DISK = 'C:\mssql-lab-backup\Lab_log1.trn'
WITH INIT, NAME = N'로그1';

-- 무엇이 들어 있습니까
RESTORE HEADERONLY FROM DISK = 'C:\mssql-lab-backup\Lab_full.bak';

-- 어떤 파일들로 이루어져 있습니까
RESTORE FILELISTONLY FROM DISK = 'C:\mssql-lab-backup\Lab_full.bak';

-- 이 파일이 성한가
RESTORE VERIFYONLY FROM DISK = 'C:\mssql-lab-backup\Lab_full.bak';

USE MssqlLabBak;
GO
SELECT COUNT(*) FROM dbo.T_LOG;
SELECT CONVERT(varchar(23), SYSDATETIME(), 121) AS 사고직전시각;
GO

-- 사고가 납니다. WHERE 를 빠뜨렸다고 합시다.
DELETE FROM dbo.T_LOG;
SELECT COUNT(*) FROM dbo.T_LOG;

USE master;
GO
BACKUP LOG MssqlLabBak
TO DISK = 'C:\mssql-lab-backup\Lab_log2.trn'
WITH INIT, NAME = N'로그2 — 사고 뒤';

USE master;
GO
ALTER DATABASE MssqlLabBak SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
GO

-- 1. 전체 백업을 올립니다. 아직 열지 않습니다.
RESTORE DATABASE MssqlLabBak
FROM DISK = 'C:\mssql-lab-backup\Lab_full.bak'
WITH NORECOVERY, REPLACE;
GO

-- 2. 차등을 얹습니다. 전체 백업 뒤의 변화가 한 번에 따라옵니다.
RESTORE DATABASE MssqlLabBak
FROM DISK = 'C:\mssql-lab-backup\Lab_diff.bak'
WITH NORECOVERY;
GO

-- 3. 로그를 그 시각까지만 적용하고 엽니다.
RESTORE LOG MssqlLabBak
FROM DISK = 'C:\mssql-lab-backup\Lab_log2.trn'
WITH RECOVERY, STOPAT = '2026-09-03 20:27:04.573';
GO

ALTER DATABASE MssqlLabBak SET MULTI_USER;

-- 흔한 계획입니다.
--   일요일 새벽   전체
--   그 밖의 새벽  차등
--   15분마다      로그

-- 마지막 백업이 언제였는지 늘 확인할 수 있게 해 두십시오.
SELECT d.name AS DB, d.recovery_model_desc AS 복구모델,
       MAX(CASE WHEN b.type = 'D' THEN b.backup_finish_date END) AS 마지막전체,
       MAX(CASE WHEN b.type = 'I' THEN b.backup_finish_date END) AS 마지막차등,
       MAX(CASE WHEN b.type = 'L' THEN b.backup_finish_date END) AS 마지막로그
FROM sys.databases d
    LEFT JOIN msdb.dbo.backupset b ON b.database_name = d.name
WHERE d.database_id > 4
GROUP BY d.name, d.recovery_model_desc;